注册表编辑工具 RegCool v1.128 绿色单文件

简介

RegCool，一款免费的Windows注册表编辑、管理工具，高级注册表编辑器、注册表快速跳转工具。具有注册表快照（妈妈再也不用担心我注册表出问题啦）、注册表比较、整理注册表，搜索和替换、多个撤销和重做操作，查找和替换所需注册项/键值/字符串等功能；可以编辑注册表文件如同系统自带的注册表编辑器一样，并且提供注册表比较功能以及便捷的收藏夹跳转功能。

截图

更新

kurtzimmermann.com/regcoolversions_de.html

RegCool相比RegWorkshop有什么区别？

RegWorkshop有资源管理器扩展右键菜单，而RegCool则无；

RegCool免费，两者功能都一样，RegWorkshop几年没更新。

关于

• 基于32位版，脱UXP壳修复，去时间过期提示，
• 去64位系统使用限制，去检测升级提示及菜单项。
• NSIS打包单文件，支持保存设置到%AppData%。

;NSIS单文件打包脚本，支持传递参数，可防交多开
;*定义变量
!define APP "RegCool" ; 程序主要名（不带空格）
!define VER "v1.128" ; 版本号
!define APPDIR "$APPDATA${APP}" ;主程序解包路径
!define /date DATE "%Y.%m.%d.%H" ;定义DATE为年%m.月%m.日%d.时%H
!define TIMEVER "Build ${DATE}" ;定义TIMEVER为 Build 年月日时
;*基本信息
Caption "${APP}" ;标题栏显示文字
OutFile "${APP}_${VER}.exe" ;指定成品输出的路径和文件名
Icon "103.ico" ;设置程序的ico图标
;*常规属性设置
Unicode true
;打开Unicode字符
SilentInstall silent
;设置为静默安装
AutoCloseWindow True
;安装完成的时候窗口自动关闭
!include "FileFunc.nsh"
;加入FileFunc头文件，获取命令行参数会用到
SetCompressor /SOLID lzma
;指定压缩方式/所有的数据将被压缩在一个区块里，这样可以提高压缩率。
SetCompressorDictSize 32
;设置使用 LZMA 压缩器时的字典大小 (默认为 8MB)
RequestExecutionLevel admin
;安装程序需要的执行级别none|user|highest|admin。设为默认值none将由Windows来判断执行级别,none和admin实际上具有相同效果。
SetOverwrite off
;File命令文件是否覆盖。on全覆盖;off全不覆盖;try默认覆盖,覆盖不了的就略过;ifnewer只有旧文件被覆盖;ifdiff新旧不一的文件才被覆盖,且设为新文件的日期。
;*版本信息
VIProductVersion "${DATE}" ;在文件属性版本表格的顶部添加产品版本号。
VIAddVersionKey /LANG=2052 "FileDescription" "${APP}_${VER}" ;文件说明
VIAddVersionKey /LANG=2052 "ProductName" "${APP}" ;产品名称
VIAddVersionKey /LANG=2052 "ProductVersion" "${VER}" ;产品版本
VIAddVersionKey /LANG=2052 "FileVersion" "${TIMEVER}" ;版本号
;*程序运行
Section "main" ;创建区段，名称为main
;程序运行前
SetOutPath "${APPDIR}" ;设置文件解压路径，且当路径不存在时创建
File /a /r "${APP}\*" ;解压一个文件夹，同时也指定了该文件夹打包的来源路径
${GetParameters} $R1 ;获取命令行参数到用户变量R1
;启动主程序
Execwait '"${APPDIR}\RegCool.exe" $R1' ;运行程序，支持传递参数
;程序运行后
SetOutPath "$APPDATA" ;再次设置解压路径，可完全删除文件夹
FIndWindow $2 "" "RegCool"
StrCmp $2 "0" 0 +2 ;防止交叉运行误删
Delete /REBOOTOK "${APPDIR}\RegCool.exe" ;仅删除释放的程序；
;RMDir /r /REBOOTOK "${APPDIR}\Settings" ;保留软件配置文件
SectionEnd ;区段结束